WindKer'Blog

asp验证码，很不错

470280558@qq.com(WindKer) — Fri,03 Sep 2010 10:04:38 +0800

 程序代码


<%
Const nMaxSaturation = 100            ' 最大色彩饱和度
Const nBlankNoisyDotOdds = 0  ' 空白处噪点率
Const nColorNoisyDotOdds = 0 ' 有色处噪点率
Const nCharCount = 4                        ' 产生的字符个数
Const nPixelWidth = 15                    ' 单个字符位图的宽度
Const nPixelHeight = 15                   ' 单个字符位图的高度
Const nColorHue = -2                        ' 显示验证码的色调(-1表示随机色调, -2表示灰度色调)
Const nAngleRandom = 0         ' 角度随机量
Const nLengthRandom = 0        ' 长度随机量(百分比)
Const cCharSet = "0123456789"
                                ' 构成验证码的字符集
                                ' 如果扩充了下边的字母矢量库，则可以相应扩充这个字符集

Dim Buf(), DigtalStr
Dim Lines(), LineCount
Dim CursorX, CursorY, DirX, DirY

Randomize
Call CreatValidCode("CheckCode")

Sub CDGen_Reset()
    ' 复位矢量笔和环境变量
    LineCount = 0
    CursorX = 0
    CursorY = 0
    ' 初始的光笔方向是垂直向下
    DirX = 0
    DirY = 1
End Sub

Sub CDGen_Clear()
    ' 清空位图阵列
    Dim i, j
    ReDim Buf(nPixelHeight - 1, nCharCount * nPixelWidth - 1)

    For j = 0 To nPixelHeight - 1
        For i = 0 To nCharCount * nPixelWidth - 1
            Buf(j, i) = 0
        Next
    Next
End Sub

Sub CDGen_PSet(X, Y)
    ' 在位图阵列上画点
    Buf(Y, X) = 1
End Sub

Sub CDGen_Line(X1, Y1, X2, Y2)
    ' 在位图阵列上画线
    Dim DX, DY, DeltaT, i
    
    DX = X2 - X1
    DY = Y2 - Y1
    If Abs(DX) > Abs(DY) Then DeltaT = Abs(DX) Else DeltaT = Abs(DY)
    For i = 0 To DeltaT
        CDGen_PSet X1 + DX * i / DeltaT, Y1 + DY * i / DeltaT
    Next
End Sub

Sub CDGen_FowardDraw(nLength)
    ' 按当前光笔方向绘制指定长度并移动光笔，正数表示从左向右/从上向下绘制，负数表示从右向左/从下向上绘制
    nLength = Sgn(nLength) * Abs(nLength) * (1 - nLengthRandom / 100 + Rnd * nLenghtRandom * 2 / 100)
    ReDim Preserve Lines(3, LineCount)
    Lines(0, LineCount) = CursorX
    Lines(1, LineCount) = CursorY
    CursorX = CursorX + DirX * nLength
    CursorY = CursorY + DirY * nLength
    Lines(2, LineCount) = CursorX
    Lines(3, LineCount) = CursorY
    LineCount = LineCount + 1
End Sub

Sub CDGen_SetDirection(nAngle)
    ' 按指定角度设定画笔方向, 正数表示相对当前方向顺时针改变方向，负数表示相对当前方向逆时针改变方向
    Dim DX, DY
    
    nAngle = Sgn(nAngle) * (Abs(nAngle) - nAngleRandom + Rnd * nAngleRandom * 2) / 180 * 3.1415926
    DX = DirX
    DY = DirY
    DirX = DX * Cos(nAngle) - DY * Sin(nAngle)
    DirY = DX * Sin(nAngle) + DY * Cos(nAngle)
End Sub

Sub CDGen_MoveToMiddle(nActionIndex, nPercent)
    ' 将画笔光标移动到指定动作的中间点上，nPercent为中间位置的百分比
    Dim DeltaX, DeltaY
    
    DeltaX = Lines(2, nActionIndex) - Lines(0, nActionIndex)
    DeltaY = Lines(3, nActionIndex) - Lines(1, nActionIndex)
    CursorX = Lines(0, nActionIndex) + Sgn(DeltaX) * Abs(DeltaX) * nPercent / 100
    CursorY = Lines(1, nActionIndex) + Sgn(DeltaY) * Abs(DeltaY) * nPercent / 100
End Sub

Sub CDGen_MoveCursor(nActionIndex)
    ' 将画笔光标移动到指定动作的起始点上
    CursorX = Lines(0, nActionIndex)
    CursorY = Lines(1, nActionIndex)
End Sub

Sub CDGen_Close(nActionIndex)
    ' 将当前光笔位置与指定动作的起始点闭合并移动光笔
    ReDim Preserve Lines(3, LineCount)
    Lines(0, LineCount) = CursorX
    Lines(1, LineCount) = CursorY
    CursorX = Lines(0, nActionIndex)
    CursorY = Lines(1, nActionIndex)
    Lines(2, LineCount) = CursorX
    Lines(3, LineCount) = CursorY
    LineCount = LineCount + 1
End Sub

Sub CDGen_CloseToMiddle(nActionIndex, nPercent)
    ' 将当前光笔位置与指定动作的中间点闭合并移动光笔，nPercent为中间位置的百分比
    Dim DeltaX, DeltaY
    
    ReDim Preserve Lines(3, LineCount)
    Lines(0, LineCount) = CursorX
    Lines(1, LineCount) = CursorY
    DeltaX = Lines(2, nActionIndex) - Lines(0, nActionIndex)
    DeltaY = Lines(3, nActionIndex) - Lines(1, nActionIndex)
    CursorX = Lines(0, nActionIndex) + Sgn(DeltaX) * Abs(DeltaX) * nPercent / 100
    CursorY = Lines(1, nActionIndex) + Sgn(DeltaY) * Abs(DeltaY) * nPercent / 100
    Lines(2, LineCount) = CursorX
    Lines(3, LineCount) = CursorY
    LineCount = LineCount + 1
End Sub

Sub CDGen_Flush(X0, Y0)
    ' 按照当前的画笔动作序列绘制位图点阵
    Dim MaxX, MinX, MaxY, MinY
    Dim DeltaX, DeltaY, StepX, StepY, OffsetX, OffsetY
    Dim i

    MaxX = MinX = MaxY = MinY = 0
    For i = 0 To LineCount - 1
        If MaxX < Lines(0, i) Then MaxX = Lines(0, i)
        If MaxX < Lines(2, i) Then MaxX = Lines(2, i)
        If MinX > Lines(0, i) Then MinX = Lines(0, i)
        If MinX > Lines(2, i) Then MinX = Lines(2, i)
        If MaxY < Lines(1, i) Then MaxY = Lines(1, i)
        If MaxY < Lines(3, i) Then MaxY = Lines(3, i)
        If MinY > Lines(1, i) Then MinY = Lines(1, i)
        If MinY > Lines(3, i) Then MinY = Lines(3, i)
    Next
    DeltaX = MaxX - MinX
    DeltaY = MaxY - MinY
    If DeltaX = 0 Then DeltaX = 1
    If DeltaY = 0 Then DeltaY = 1
    MaxX = MinX
    MaxY = MinY
    If DeltaX > DeltaY Then
        StepX = (nPixelWidth - 2) / DeltaX
        StepY = (nPixelHeight - 2) / DeltaX
        OffsetX = 0
        OffsetY = (DeltaX - DeltaY) / 2
    Else
        StepX = (nPixelWidth - 2) / DeltaY
        StepY = (nPixelHeight - 2) / DeltaY
        OffsetX = (DeltaY - DeltaX) / 2
        OffsetY = 0
    End If
    For i = 0 To LineCount - 1
        Lines(0, i) = Round((Lines(0, i) - MaxX + OffsetX) * StepX, 0)
        If Lines(0, i) < 0 Then Lines(0, i) = 0
        If Lines(0, i) >= nPixelWidth - 2 Then Lines(0, i) = nPixelWidth - 3
        Lines(1, i) = Round((Lines(1, i) - MaxY + OffsetY) * StepY, 0)
        If Lines(1, i) < 0 Then Lines(1, i) = 0
        If Lines(1, i) >= nPixelHeight - 2 Then Lines(1, i) = nPixelHeight - 3
        Lines(2, i) = Round((Lines(2, i) - MinX + OffsetX) * StepX, 0)
        If Lines(2, i) < 0 Then Lines(2, i) = 0
        If Lines(2, i) >= nPixelWidth - 2 Then Lines(2, i) = nPixelWidth - 3
        Lines(3, i) = Round((Lines(3, i) - MinY + OffsetY) * StepY, 0)
        If Lines(3, i) < 0 Then Lines(3, i) = 0
        If Lines(3, i) >= nPixelHeight - 2 Then Lines(3, i) = nPixelHeight - 3
        CDGen_Line Lines(0, i) + X0 + 1, Lines(1, i) + Y0 + 1, Lines(2, i) + X0 + 1, Lines(3, i) + Y0 + 1
    Next
End Sub

Sub CDGen_Char(cChar, X0, Y0)
    ' 在指定坐标处生成指定字符的位图阵列
    CDGen_Reset
    Select Case cChar
    Case "0"
        CDGen_SetDirection -60                            ' 逆时针60度(相对于垂直线)
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection -60                            ' 逆时针60度
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection 120                            ' 顺时针120度
        CDGen_FowardDraw 1.5                              ' 绘制1.5个单位
        CDGen_SetDirection -60                            ' 逆时针60度
        CDGen_FowardDraw 0.7                              ' 绘制0.7个单位
        CDGen_SetDirection -60                            ' 顺时针120度
        CDGen_FowardDraw 0.7                              ' 绘制0.7个单位
        CDGen_Close 0                                     ' 封闭当前笔与第0笔(0开始)
    Case "1"
        CDGen_SetDirection -90                            ' 逆时针90度(相对于垂直线)
        CDGen_FowardDraw 0.5                              ' 绘制0.5个单位
        CDGen_MoveToMiddle 0, 50                          ' 移动画笔的位置到第0笔(0开始)的50%处
        CDGen_SetDirection 90                             ' 逆时针90度
        CDGen_FowardDraw -1.4                             ' 反方向绘制1.4个单位
        CDGen_SetDirection 30                             ' 逆时针30度
        CDGen_FowardDraw 0.4                              ' 绘制0.4个单位
    Case "2"
        CDGen_SetDirection 45                             ' 顺时针45度(相对于垂直线)
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection -120                           ' 逆时针120度
        CDGen_FowardDraw 0.4                              ' 绘制0.4个单位
        CDGen_SetDirection 60                             ' 顺时针60度
        CDGen_FowardDraw 0.6                              ' 绘制0.6个单位
        CDGen_SetDirection 60                             ' 顺时针60度
        CDGen_FowardDraw 1.6                              ' 绘制1.6个单位
        CDGen_SetDirection -135                           ' 逆时针135度
        CDGen_FowardDraw 1.0                              ' 绘制1.0个单位
    Case "3"
        CDGen_SetDirection -90                            ' 逆时针90度(相对于垂直线)
        CDGen_FowardDraw 0.8                              ' 绘制0.8个单位
        CDGen_SetDirection 135                            ' 顺时针135度
        CDGen_FowardDraw 0.8                              ' 绘制0.8个单位
        CDGen_SetDirection -120                           ' 逆时针120度
        CDGen_FowardDraw 0.6                              ' 绘制0.6个单位
        CDGen_SetDirection 80                             ' 顺时针80度
        CDGen_FowardDraw 0.5                              ' 绘制0.5个单位
        CDGen_SetDirection 60                             ' 顺时针60度
        CDGen_FowardDraw 0.5                              ' 绘制0.5个单位
        CDGen_SetDirection 60                             ' 顺时针60度
        CDGen_FowardDraw 0.5                              ' 绘制0.5个单位
    Case "4"
        CDGen_SetDirection 20                             ' 顺时针20度(相对于垂直线)
        CDGen_FowardDraw 0.8                              ' 绘制0.8个单位
        CDGen_SetDirection -110                           ' 逆时针110度
        CDGen_FowardDraw 1.2                              ' 绘制1.2个单位
        CDGen_MoveToMiddle 1, 60                          ' 移动画笔的位置到第1笔(0开始)的60%处
        CDGen_SetDirection 90                             ' 顺时针90度
        CDGen_FowardDraw 0.7                              ' 绘制0.7个单位
        CDGen_MoveCursor 2                                ' 移动画笔到第2笔(0开始)的开始处
        CDGen_FowardDraw -1.5                             ' 反方向绘制1.5个单位
    Case "5"
        CDGen_SetDirection 90                             ' 顺时针90度(相对于垂直线)
        CDGen_FowardDraw 1.0                              ' 绘制1.0个单位
        CDGen_SetDirection -90                            ' 逆时针90度
        CDGen_FowardDraw 0.8                              ' 绘制0.8个单位
        CDGen_SetDirection -90                            ' 逆时针90度
        CDGen_FowardDraw 0.8                              ' 绘制0.8个单位
        CDGen_SetDirection 30                             ' 顺时针30度
        CDGen_FowardDraw 0.4                              ' 绘制0.4个单位
        CDGen_SetDirection 60                             ' 顺时针60度
        CDGen_FowardDraw 0.4                              ' 绘制0.4个单位
        CDGen_SetDirection 30                             ' 顺时针30度
        CDGen_FowardDraw 0.5                              ' 绘制0.5个单位
        CDGen_SetDirection 60                             ' 顺时针60度
        CDGen_FowardDraw 0.8                              ' 绘制0.8个单位
    Case "6"
        CDGen_SetDirection -60                            ' 逆时针60度(相对于垂直线)
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection -60                            ' 逆时针60度
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection 120                            ' 顺时针120度
        CDGen_FowardDraw 1.5                              ' 绘制1.5个单位
        CDGen_SetDirection 120                            ' 顺时针120度
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection 120                            ' 顺时针120度
        CDGen_FowardDraw 0.7                              ' 绘制0.7个单位
        CDGen_SetDirection 120                            ' 顺时针120度
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection 120                            ' 顺时针120度
        CDGen_FowardDraw 0.5                              ' 绘制0.5个单位
        CDGen_CloseToMiddle 2, 50                         ' 将当前画笔位置与第2笔(0开始)的50%处封闭
    Case "7"
        CDGen_SetDirection 180                            ' 顺时针180度(相对于垂直线)
        CDGen_FowardDraw 0.3                              ' 绘制0.3个单位
        CDGen_SetDirection 90                             ' 顺时针90度
        CDGen_FowardDraw 0.9                              ' 绘制0.9个单位
        CDGen_SetDirection 120                            ' 顺时针120度
        CDGen_FowardDraw 1.3                              ' 绘制1.3个单位
    Case "8"
        CDGen_SetDirection -60                            ' 逆时针60度(相对于垂直线)
        CDGen_FowardDraw -0.8                             ' 反方向绘制0.8个单位
        CDGen_SetDirection -60                            ' 逆时针60度
        CDGen_FowardDraw -0.8                             ' 反方向绘制0.8个单位
        CDGen_SetDirection 120                            ' 顺时针120度
        CDGen_FowardDraw 0.8                              ' 绘制0.8个单位
        CDGen_SetDirection 110                            ' 顺时针110度
        CDGen_FowardDraw -1.5                             ' 反方向绘制1.5个单位
        CDGen_SetDirection -110                           ' 逆时针110度
        CDGen_FowardDraw 0.9                              ' 绘制0.9个单位
        CDGen_SetDirection 60                             ' 顺时针60度
        CDGen_FowardDraw 0.8                              ' 绘制0.8个单位
        CDGen_SetDirection 60                             ' 顺时针60度
        CDGen_FowardDraw 0.8                              ' 绘制0.8个单位
        CDGen_SetDirection 60                             ' 顺时针60度
        CDGen_FowardDraw 0.9                              ' 绘制0.9个单位
        CDGen_SetDirection 70                             ' 顺时针70度
        CDGen_FowardDraw 1.5                                ' 绘制1.5个单位
        CDGen_Close 0                                     ' 封闭当前笔与第0笔(0开始)
    Case "9"
        CDGen_SetDirection 120                            ' 逆时针60度(相对于垂直线)
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection -60                            ' 逆时针60度
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection -60                            ' 顺时针120度
        CDGen_FowardDraw -1.5                              ' 绘制1.5个单位
        CDGen_SetDirection -60                            ' 顺时针120度
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection -60                            ' 顺时针120度
        CDGen_FowardDraw -0.7                              ' 绘制0.7个单位
        CDGen_SetDirection 120                            ' 顺时针120度
        CDGen_FowardDraw 0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection -60                            ' 顺时针120度
        CDGen_FowardDraw 0.5                              ' 绘制0.5个单位
        CDGen_CloseToMiddle 2, 50                         ' 将当前画笔位置与第2笔(0开始)的50%处封闭
    ' 以下为字母的矢量动作，有兴趣的可以继续
    Case "A"
        CDGen_SetDirection -(Rnd * 20 + 150)              ' 逆时针150-170度(相对于垂直线)
        CDGen_FowardDraw Rnd * 0.2 + 1.1                  ' 绘制1.1-1.3个单位
        CDGen_SetDirection Rnd * 20 + 140                 ' 顺时针140-160度
        CDGen_FowardDraw Rnd * 0.2 + 1.1                  ' 绘制1.1-1.3个单位
        CDGen_MoveToMiddle 0, 30                          ' 移动画笔的位置到第1笔(0开始)的30%处
        CDGen_CloseToMiddle 1, 70                         ' 将当前画笔位置与第1笔(0开始)的70%处封闭
    Case "B"
        CDGen_SetDirection -(Rnd * 20 + 50)               ' 逆时针50-70度(相对于垂直线)
        CDGen_FowardDraw Rnd * 0.4 + 0.8                  ' 绘制0.8-1.2个单位
        CDGen_SetDirection Rnd * 20 + 110                 ' 顺时针110-130度
        CDGen_FowardDraw Rnd * 0.2 + 0.6                  ' 绘制0.6-0.8个单位
        CDGen_SetDirection -(Rnd * 20 + 110)              ' 逆时针110-130度
        CDGen_FowardDraw Rnd * 0.2 + 0.6                  ' 绘制0.6-0.8个单位
        CDGen_SetDirection Rnd * 20 + 110                 ' 顺时针110-130度
        CDGen_FowardDraw Rnd * 0.4 + 0.8                  ' 绘制0.8-1.2个单位
        CDGen_Close 0                                     ' 封闭当前笔与第1笔(0开始)
    Case "C"
        CDGen_SetDirection -60                            ' 逆时针60度(相对于垂直线)
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection -60                            ' 逆时针60度
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection 120                            ' 顺时针120度
        CDGen_FowardDraw 1.5                              ' 绘制1.5个单位
        CDGen_SetDirection 120                            ' 顺时针120度
        CDGen_FowardDraw -0.7                             ' 反方向绘制0.7个单位
        CDGen_SetDirection 120                            ' 顺时针120度
        CDGen_FowardDraw 0.7                              ' 绘制0.7个单位
    End Select
    CDGen_Flush X0, Y0
End Sub

Sub CDGen_Blur()
    ' 对产生的位图进行柔化处理
    Dim i, j
    
    For j = 1 To nPixelHeight - 2
        For i = 1 To nCharCount * nPixelWidth - 2
            If Buf(j, i) = 0 Then
                If ((Buf(j, i - 1) or Buf(j + 1, i)) And 1) <> 0 Then
                    ' 如果当前点是空白点，且上下左右四个点中有一个点是有色点，则该点做柔化处理
                    Buf(j, i) = 2
                End If
            End If
        Next
    Next
End Sub

Sub CDGen_NoisyDot()
    ' 对产生的位图进行噪点处理
    Dim i, j, NoisyDot, CurDot
    
    For j = 0 To nPixelHeight - 1
        For i = 0 To nCharCount * nPixelWidth - 1
            If Buf(j, i) <> 0 Then
                NoisyDot = Int(Rnd * Rnd * nMaxSaturation)
                Select Case nColorNoisyDotOdds
                Case 0
                    CurDot = nMaxSaturation
                Case 1
                    CurDot = 0
                Case Else
                    CurDot = NoisyDot
                End Select
                If Rnd < nColorNoisyDotOdds Then Buf(j, i) = CurDot Else Buf(j, i) = nMaxSaturation
            Else
                NoisyDot = Int(Rnd * nMaxSaturation)
                Select Case nBlankNoisyDotOdds
                Case 0
                    CurDot = 0
                Case 1
                    CurDot = nMaxSaturation
                Case Else
                    CurDot = NoisyDot
                End Select
                If Rnd < nBlankNoisyDotOdds Then Buf(j, i) = CurDot Else Buf(j, i) = 0
            End If
        Next
    Next
End Sub

Sub CDGen()
    ' 生成位图阵列
    Dim i, Ch
    
    DigtalStr = ""
    CDGen_Clear
    For i = 0 To nCharCount - 1
        Ch = Mid(cCharSet, Int(Rnd * Len(cCharSet)) + 1, 1)
        DigtalStr = DigtalStr + Ch
        CDGen_Char Ch, i * nPixelWidth, 0
    Next
    CDGen_Blur
    CDGen_NoisyDot
End Sub

Function HSBToRGB(vH, vS, vB)
    ' 将颜色值由HSB转换为RGB
    Dim aRGB(3), RGB1st, RGB2nd, RGB3rd
    Dim nH, nS, nB
    Dim lH, nF, nP, nQ, nT

    vH = (vH Mod 360)
    If vS > 100 Then
        vS = 100
    ElseIf vS < 0 Then
        vS = 0
    End If
    If vB > 100 Then
        vB = 100
    ElseIf vB < 0 Then
        vB = 0
    End If
    If vS > 0 Then
        nH = vH / 60
        nS = vS / 100
        nB = vB / 100
        lH = Int(nH)
        nF = nH - lH
        nP = nB * (1 - nS)
        nQ = nB * (1 - nS * nF)
        nT = nB * (1 - nS * (1 - nF))
        Select Case lH
        Case 0
            aRGB(0) = nB * 255
            aRGB(1) = nT * 255
            aRGB(2) = nP * 255
        Case 1
            aRGB(0) = nQ * 255
            aRGB(1) = nB * 255
            aRGB(2) = nP * 255
        Case 2
            aRGB(0) = nP * 255
            aRGB(1) = nB * 255        
            aRGB(2) = nT * 255
        Case 3
            aRGB(0) = nP * 255
            aRGB(1) = nQ * 255
            aRGB(2) = nB * 255
        Case 4
            aRGB(0) = nT * 255
            aRGB(1) = nP * 255
            aRGB(2) = nB * 255
        Case 5
            aRGB(0) = nB * 255
            aRGB(1) = nP * 255
            aRGB(2) = nQ * 255
        End Select            
    Else
        aRGB(0) = (vB * 246) / 100
        aRGB(1) = aRGB(0)
        aRGB(2) = aRGB(0)
    End If
    HSBToRGB = ChrB(Round(aRGB(2), 0)) & ChrB(Round(aRGB(1), 0)) & ChrB(Round(aRGB(0), 0))
End Function

Sub CreatValidCode(pSN)
    Dim i, j, CurColorHue
    
    ' 禁止缓存
    Response.Expires = -9999
    Response.AddHeader "pragma", "no-cache"
    Response.AddHeader "cache-ctrol", "no-cache"
    Response.ContentType = "image/bmp"
    
    Call CDGen
    Session(pSN) = DigtalStr    '记录入Session

    Dim PicWidth, PicHeight, FileSize, PicDataSize
    PicWidth = nCharCount * nPixelWidth
    PicHeight = nPixelHeight
    PicDataSize = PicWidth * PicHeight * 3
    FileSize = PicDataSize + 54

    ' 输出BMP文件信息头
    Response.BinaryWrite ChrB(66) & ChrB(77) & _
        ChrB(FileSize Mod 256) & ChrB((FileSize \ 256) Mod 256) & ChrB((FileSize \ 256 \ 256) Mod 256) & ChrB(FileSize \ 256 \ 256 \ 256) & _
        ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0) & _
        ChrB(54) & ChrB(0) & ChrB(0) & ChrB(0)

    ' 输出BMP位图信息头
    Response.BinaryWrite ChrB(40) & ChrB(0) & ChrB(0) & ChrB(0) & _
        ChrB(PicWidth Mod 256) & ChrB((PicWidth \ 256) Mod 256) & ChrB((PicWidth \ 256 \ 256) Mod 256) & ChrB(PicWidth \ 256 \ 256 \ 256) & _
        ChrB(PicHeight Mod 256) & ChrB((PicHeight \ 256) Mod 256) & ChrB((PicHeight \ 256 \ 256) Mod 256) & ChrB(PicHeight \ 256 \ 256 \ 256) & _
        ChrB(1) & ChrB(0) & _
        ChrB(24) & ChrB(0) & _
        ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0) & _
        ChrB(PicDataSize Mod 256) & ChrB((PicDataSize \ 256) Mod 256) & ChrB((PicDataSize \ 256 \ 256) Mod 256) & ChrB(PicDataSize \ 256 \ 256 \ 256) & _
        ChrB(18) & ChrB(11) & ChrB(0) & ChrB(0) & _
        ChrB(18) & ChrB(11) & ChrB(0) & ChrB(0) & _
        ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0) & _
        ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0)

    ' 逐点输出位图阵列
    If nColorHue = -1 Then
        CurColorHue = Int(Rnd * 360)
    ElseIf nColorHue = -2 Then
        CurColorHue = 0
    Else
        CurColorHue = nColorHue
    End If
    For j = 0 To nPixelHeight - 1
        For i = 0 To Len(DigtalStr) * nPixelWidth - 1
            If nColorHue = -2 Then
                Response.BinaryWrite HSBToRGB(CurColorHue, 0, 100 - Buf(nPixelHeight - 1 - j, i))
            Else
                Response.BinaryWrite HSBToRGB(CurColorHue, Buf(nPixelHeight - 1 - j, i), 100)
            End If
        Next
    Next
End Sub
%>

将代码保存为.asp文件
获取方式

获取session为Session("CheckCode"),修改session的名称在第20行

右键添加到QQ表情没了解决方法

470280558@qq.com(WindKer) — Thu,02 Sep 2010 20:21:01 +0800

安装了新版了2010QQ，看到好的图片想保存到QQ表情里面
竟然发现右键的添加到QQ表情没有
搜了下，一下是可行的方法：

1、开始——运行——输入regedit
2、按Ctrl+F，输入MenuExt （或手动查找，路径为：[HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\MenuExt）
3、右击"MenuExt"文件夹——新建——项,项名字为“添加到QQ表情”
4、在右边“名称”下第一个图标（上有"ab"字样）右击——修改，数值数据填入“QQ安装路径\BIN\AddEmotion.htm”（安装盘为

C或D）
5、右边空白处右击——新建“DWORD值”，名字为“contexts”，数值数据为“2”

退出注册表编辑器，重新打开IE

恢复“显示桌面”快捷键

470280558@qq.com(WindKer) — Wed,01 Sep 2010 19:27:09 +0800

发送到桌面，再放到快速启动栏里：C:\Documents and Settings\Administrator\Application Data\Microsoft\Internet Explorer\Quick Launch

可以自己做一个。
打开记事本，输入以下内容：

[Shell]
Command=2
IconFile=explorer.exe,3
[Taskbar]
Command=ToggleDesktop

然后点“文件”——>“另存为”，在文件类型中选择"所有文件"，在文件名中打上“显示桌面.scf”（不包括双引号）就成了。
最后用鼠标把它拖到快速启动栏里就OK了。

PHP下载CSS文件中的图片

470280558@qq.com(WindKer) — Sat,21 Aug 2010 10:46:42 +0800

代码如下

< ?php
//note 设置PHP超时时间
set_time_limit(0);
//note 取得样式文件内容
$styleFileContent = file_get_contents('images/style.css');

//note 匹配出需要下载的URL地址

preg_match_all("/url((.*))/", $styleFileContent, $imagesURLArray);

//note 循环需要下载的地址，逐个下载

//array_unique是移除数组中重复的元素

$imagesURLArray = array_unique($imagesURLArray[1]);

foreach($imagesURLArray as $imagesURL) {

file_put_contents(basename($imagesURL), file_get_contents($imagesURL));

}

主要里面正则表达式和内置文件操作函数
网络转载

php输出一个简单xml示例

470280558@qq.com(WindKer) — Thu,19 Aug 2010 23:27:41 +0800

date_default_timezone_set("Asia/Shanghai");
header("Expires: -1");
header("Last-Modified: " . gmdate("D, d M Y H:i:s") . "GMT");
header("Cache-Control: no-cache, must-revalidate");
header("Pragma: no-cache");
header('Content-Type: text/xml');
echo "\n";
echo "\n";
echo ''.date('His')."\n";
echo ''.date('Ymd')."\n";
echo "\n";

?>
转自：http://lhdeyx.blog.163.com/blog/static/3181969720096168821978/
我有遇到这样的问题，也是用PHP输出xml的，我在顶部包含了公用文件，
运行时候出错了，所以如果遇到此问题可以试试是不是这个文件，当然我做的程序比较，
不一定完全正确，只是提示下，少走弯路。作者的博客有很多好东西，大家可以去看下。。

php 利用header下载文件

470280558@qq.com(WindKer) — Thu,19 Aug 2010 23:21:37 +0800

你希望客户要填完一份表格，然后就将网址指到该文件，这样客户才能下载，但如果你想做一个关于"网上购物"的电子商务网站，考虑安全问题，你不想用户直接复制网址下载该文件，笔者建议你使用PHP直接读取该实际文件然后下载的方法去做。程序如下：

一


$file_name = "info_check.exe";
$file_dir = "/public/www/download/";
if (!file_exists($file_dir . $file_name)) { //检查文件是否存在
echo "文件找不到";
exit;
} else {
$file = fopen($file_dir . $file_name,"r"); // 打开文件
// 输入文件标签
Header("Content-type: application/octet-stream");
Header("Accept-Ranges: bytes");
Header("Accept-Length: ".filesize($file_dir . $file_name));
Header("Content-Disposition: attachment; filename=" . $file_name);
// 输出文件内容
echo fread($file,filesize($file_dir . $file_name));
fclose($file);
exit;}


二

而如果文件路径是"http" 或者 "ftp" 网址的话，则源代码会有少许改变，程序如下：

$file_name = "info_check.exe";
$file_dir = "http://www.easycn.net/";
$file = @ fopen($file_dir . $file_name,"r");
if (!$file) {
echo "文件找不到";
} else {
Header("Content-type: application/octet-stream");
Header("Content-Disposition: attachment; filename=" . $file_name);
while (!feof ($file)) {
echo fread($file,50000);
}
fclose ($file);
}

这样就可以用PHP直接输出文件了。

三

header ('Content-type: application/'.$file_ext);
header ("Expires: 0");
header ("Pragma: no-cache");
header ('Content-Disposition: attachment; filename='.$file_name.'');
header ("Content-Length: ".$file_size);
readfile ($file_name);

转自：http://lhdeyx.blog.163.com/blog/static/31819697200983010224884/

phpMyAdmin中文乱码解决方法

470280558@qq.com(WindKer) — Tue,10 Aug 2010 10:55:39 +0800

今天在弄个的时候，用phpmyadmin打开发现里面全是utf8的乱码
因为是接手过来的，这样的话对我来说很难理解里面的东西
我也是刚接触php不久，后面找了下，发现下面的方法可行：

PHPMyAdmin中文乱码问题很常见，主要是UTF-8和GB2312编码不能同时正确显示。

方法一：

1. 因为MySQL的默认编码是latin1，所以首先我们需要修改一下PHPMyAdmin的编码转换。修改libraries目录下面的select_lang.lib.php文件，将 'utf-8' => 'utf8'修改成'utf-8' => 'latin1'。

2. 接下来还要修改一下页面的编码显示，将 'zh-gb2312' => array('zh|chinese simplified', 'chinese_simplified-gb2312', 'zh')修改成 'zh-gb2312-utf-8' => array('zh|chinese simplified', 'chinese_simplified-gb2312', 'zh'), 也就是在zh-gb2312后面增加-utf-8，这样页面编码就支持UTF-8了。

3. 首先选择zh-gb2312-utf-8进入PHPMyAdmin，这个时候浏览GB2312编码的数据正常，但是浏览UTF-8的数据是乱码。如果浏览UTF-8的数据的话，进入首页，然后在Language里面选择zh-utf-8就可以了。

4. 默认的语言编码很长，你可以将其他编码用/**/注释掉，只保留zh-gb2312-utf-8和zh-utf-8两个编码。

方法二：

也可以修改phpMyAdm的inconfig.inc.php配置文件，将$cfg['Lang'] = 'en-utf-8'改成$cfg['Lang'] = 'zh-gb2312'这样问题就解决了。

转自:http://blog.csdn.net/snlixing/archive/2008/04/04/2251977.aspx
我修改了 1和2就可以了

php配置ini_get、ini_set、ini_get_all、ini_restore

470280558@qq.com(WindKer) — Sat,24 Jul 2010 11:02:52 +0800

php的配置函数就是几个ini_*的函数，主要是针对配置文件的操作，其实就四个函数：ini_get、ini_set、ini_get_all、ini_restore。个人感觉最有用的就是ini_set和ini_get。
* ini_get()：获取配置文件的选项值

这个函数相信很多人都使过，就是获取配置文件中某一个选项的值，如果是true值就返回1，如果是false值就返回0，字符串就返回字符串。
比如手册中的例子：
/*
Our php.ini contains the following settings:

display_errors = On
register_globals = Off
post_max_size = 8M
*/
echo 'display_errors = ' . ini_get('display_errors') . "\n"; //显示错误是否打开
echo 'register_globals = ' . ini_get('register_globals') . "\n";//全局变量是否打开
echo 'post_max_size = ' . ini_get('post_max_size') . "\n";//最多能提交的文件大小
echo 'post_max_size+1 = ' . (ini_get('post_max_size')+1) . "\n";
?>

输出：
display_errors = 1
register_globals = 0
post_max_size = 8M
post_max_size+1 = 9

这个函数主要是为了获取配置文件，可以方便你很多操作。比如你想操作字符串过滤，但是又不清楚magic_quotes_gpc有没有打开，所以你就可以这样写一个函数：

/* 字符串过滤函数 */
function stringFilter($str)
{
if (ini_get('magic_quotes_gpc)') {
return $str;
} else {
return addslashes($str);
}
}
当然，如果你无法知道你的全局变量是否打开，也可以定制这样的函数：

/* 变量检测函数 */
function getGetVar($var)
{
if (ini_set('register_gobals')) {
return $var;
} else {
return $_GET['var'];
}
}
当然，你可以做很多用途，自己慢慢体会。

* ini_set函数：设置php.ini中的某些变量值

这个函数是设置选项中的值，在执行函数后生效，脚本结束的时候，这个设置也失效。不是所有的选项都能被改函数设置的。具体那些值能够设置，可以查看手册中的列表。
就是能够设置php.ini中的选项值比如，display_error选项关闭了，但是你要显示程序中的错误信息，方便你调试程序，那么就可以使用这个函数：

ini_set("display_errors", "On");

那么在你这个页面的程序都会显示错误信息了，而且你还可以使用error_reporting来设置显示的错误信息级别。
如果你需要增加脚本执行时间，那么可以设置：

ini_set("max_execution_time", "180");

那么脚本执行时间就由默认的30秒变为180秒，当然，你也可以使用set_time_limit()来设置。
其实你把ini_set和ini_get结合使的话，非常好。比如你想在配置文件里添加自己的包含文件路径，但是你有没有权限更改php.ini，那么你可以结合两个函数：

ini_set('include_path',ini_get('include_path').':/your_include_dir:');

* ini_get_all: 获取所有的设置选项变量

把所有选项值以数组的形式返回，方便你当phpinfo()无法使用的时候来使用。

手册例子，比如：

$inis = ini_get_all();

print_r($inis);

?>

部分输出：

Array
(
[allow_call_time_pass_reference] => Array
(
[global_value] => 1
[local_value] => 1
[access] => 6
)
[allow_url_fopen] => Array
(
[global_value] => 1
[local_value] => 1
[access] => 7
)
...
)

* ini_restore: 回复配置文件默认的值

转自网络

php的$_SERVER函数中QUERY_STRING和REQUEST_URI等四个变量区别

470280558@qq.com(WindKer) — Mon,28 Jun 2010 09:33:11 +0800

$_SERVER存储当前服务器信息，其中有几个值如$_SERVER["QUERY_STRING"]，$_SERVER["REQUEST_URI"]，$_SERVER["SCRIPT_NAME"] 和$_SERVER["PHP_SELF"]常常容易混淆，以下通过实例详解$_SERVER函数中 QUERY_STRING，REQUEST_URI，SCRIPT_NAME和PHP_SELF变量区别，掌握这四者之间的关系，便于在实际应用中正确获取所需要的值，供参考。

1，$_SERVER["QUERY_STRING"]
说明：查询(query)的字符串

2，$_SERVER["REQUEST_URI"]
说明：访问此页面所需的URI

3，$_SERVER["SCRIPT_NAME"]
说明：包含当前脚本的路径

4，$_SERVER["PHP_SELF"]
说明：当前正在执行脚本的文件名

实例：
1，http://www.biuuu.com/ (直接打开主页)
结果：
$_SERVER["QUERY_STRING"] = “”
$_SERVER["REQUEST_URI"]  = “/”
$_SERVER["SCRIPT_NAME"]  = “/index.php”
$_SERVER["PHP_SELF"]     = “/index.php”

2，http://www.biuuu.com/?p=222 (附带查询)
结果：
$_SERVER["QUERY_STRING"] = “p=222″
$_SERVER["REQUEST_URI"]  = “/?p=222″
$_SERVER["SCRIPT_NAME"]  = “/index.php”
$_SERVER["PHP_SELF"]     = “/index.php”

3，http://www.biuuu.com/index.php?p=222&q=biuuu
结果：
$_SERVER["QUERY_STRING"] = “p=222&q=biuuu”
$_SERVER["REQUEST_URI"]  = “/index.php?p=222&q=biuuu”
$_SERVER["SCRIPT_NAME"]  = “/index.php”
$_SERVER["PHP_SELF"]     = “/index.php”

$_SERVER["QUERY_STRING"]获取查询语句，实例中可知，获取的是?后面的值
$_SERVER["REQUEST_URI"] 获取http://www.biuuu.com后面的值，包括/
$_SERVER["SCRIPT_NAME"] 获取当前脚本的路径，如：index.php
$_SERVER["PHP_SELF"] 当前正在执行脚本的文件名

总结一下，对于QUERY_STRING，REQUEST_URI，SCRIPT_NAME和PHP_SELF，深入了解将有利于我们在$_SERVER函数中正确调用这四个值。通过实例详解$_SERVER函数中QUERY_STRING，REQUEST_URI，SCRIPT_NAME和 PHP_SELF掌握四个变量之间的区别。

转自：http://hi.baidu.com/linyang0106/blog/item/5cf17e60c6944d4eeaf8f8ec.html
仅收藏参考之用。

去掉桌面上快捷方式的图标下面的文字有蓝色的阴影

470280558@qq.com(WindKer) — Wed,09 Jun 2010 12:46:05 +0800

1、右键“我的电脑”－－属性－－高级－－“性能”栏点击“设置”－－视觉效果－勾选“在桌面上为图标标签使用阴影”，点击“应用”确定退出即可。

2、右键桌面--排列图标--在桌面上锁定WEB项目前的勾去掉

3、右击桌面空白处，依次单击“属性/桌面/自定义桌面/web”选项，将“网页”栏中的“当前主页”以及“http//......”等所有各项前面的勾全部去掉（“http//……”为从Internet添加网页或图片的地址，一般不需要，可将它们全部删除），并将下面“锁定桌面项目”前面的勾也去掉，单击确定完成设置，就又能看到可爱的桌面图标了。

4、另外有一种情况就是安装了某种程序之后(比如系统提示:是否将该Active Desktop项添加到您的桌面上)，桌面文字变的不透明。在“运行”中输入“gpedit.msc”，打开组策略；在“用户配置→管理模板→桌面→Active Desktop”中，点启用Active Desktop(活动桌面)然后点击“属性”选定“已禁用”，点禁用Active Desktop (活动桌面)“属性”选定“已启用”；之后打开控制面板，在经典视图中打开系统，在“性能→高级选项→性能→视觉效果→使桌面文字透明”（等价于在之后执行第1种方法）。

5、注册表修改法：

在“开始”--->运行--->打入“regedit”回车HKEY_USERS--->S-1-5-21-1121289129-3884528725-3932546534-1006>Software--->Microsoft--->Windows--->CurrentVersion--->Explorer--->Advanced

找到“ShowCompColor”=“dword:00000001”更改为“dword:00000000”

找到“ListviewShadow”=“dword:00000000”更改为“dword:00000001”

(更改方法为双击)

重新启动电脑

摘自百度知道